• Install Firefox silently, without Firefox being the default
• Disables the ‘Automatically check for updates’ option
• Disables the import wizard when Firefox first loads
• Disables the ‘Always check to see if Firefox is the default browser on startup’ option
• Sets homepage to ‘http://www.ravinderjaiswal.com’ (you can change this in your configuration)
• Disables the ‘know your rights’ button from displaying on first run
• Disables the request to send performance data from displaying

Download: 

How to customise and deploy (silent install) Firefox

1. Create a temporary working folder for saving the files into (for example, create C:\TEMP\Firefox)
2. 
3. Download the latest install file at http://www.mozilla.org/en-US/firefox/all . Save to C:\TEMP\Firefox
4. Create a new text file called ‘override.ini’ and copy in the following information:

[XRE]
EnableProfileMigrator=false

3. Create a new text file called ‘local-settings.js’ and copy in the folling information:

pref("general.config.obscure_value", 0);
pref("general.config.filename", "mozilla.cfg");

4. Create a new text file called ‘mozilla.cfg’ and copy in the following information:

//Firefox Default Settings
// set Firefox Default homepage
pref("browser.startup.homepage","http://www.itsupportguides.com");
// disable default browser check
pref("browser.shell.checkDefaultBrowser", false);
pref("browser.startup.homepage_override.mstone", "ignore");
// disable application updates
pref("app.update.enabled", false)
// disables the 'know your rights' button from displaying on first run
pref("browser.rights.3.shown", true);
// disables the request to send performance data from displaying
pref("toolkit.telemetry.prompted", 2);
pref("toolkit.telemetry.rejected", true);

5. Create a new text file called‘install.cmd’ and copy in the following information

@echo off
REM==========================================
REM Install FireFox 49.0.2
REM==========================================
REM  This script will:
REM       + silently install or upgrade Firefox WITHOUT Firefox being the default browser
REM       + Disables the 'Automatically check for updates' option
REM       + Disables the 'Always check to see if Firefox is the default browser on startup' option
REM       + Deletes desktop icon
REM       + Disables the Import Wizard
REM       + Works for Windows XP / 7 /8 32-bit and 64-bit
REM .
REM===========================================
echo Installing Firefox - Please Wait.
echo Window will close after install is complete
REM Installing Firefox
"%~dp0Firefox Setup 49.0.2.exe" -ms
REM Install 32-bit customisations
if exist "%programfiles%\Mozilla Firefox\" copy /Y "%~dp0override.ini" "%programfiles%\Mozilla Firefox\browser\"
if exist "%programfiles%\Mozilla Firefox\" copy /Y "%~dp0mozilla.cfg" "%programfiles%\Mozilla Firefox\"
if exist "%programfiles%\Mozilla Firefox\" copy /Y "%~dp0local-settings.js" "%programfiles%\Mozilla Firefox\defaults\pref"
REM Install 64-bit customisations
if exist "%ProgramFiles(x86)%\Mozilla Firefox\" copy /Y "%~dp0override.ini" "%ProgramFiles(x86)%\Mozilla Firefox\browser\"
if exist "%ProgramFiles(x86)%\Mozilla Firefox\" copy /Y "%~dp0mozilla.cfg" "%ProgramFiles(x86)%\Mozilla Firefox\"
if exist "%ProgramFiles(x86)%\Mozilla Firefox\" copy /Y "%~dp0local-settings.js" "%ProgramFiles(x86)%\Mozilla Firefox\defaults\pref"
REM Removes Firefox Desktop Icon - Windows XP
if exist "%allusersprofile%\Desktop\Mozilla Firefox.lnk" del "%allusersprofile%\Desktop\Mozilla Firefox.lnk" /S
REM Removes Firefox Desktop Icon - Windows 7 / 8
if exist "%public%\Desktop\Mozilla Firefox.lnk" del "%public%\Desktop\Mozilla Firefox.lnk"

6. Copy the Firefox install file, override.ini, mozilla.cfg, local-settings.js and install.cmd to your software package share
6. 
7. You can now create your SCCM package or deploy the software by using install.cmd.